쌓고 쌓다

Function Module에서 SELECT-OPTIONS 사용하기

승민아 — Sat, 16 May 2026 23:39:09 +0900

SELECT-OPTIONS를 Function Moudle에서 가져와 SELECT 조건으로 사용하고 싶다.

어떻게 화면에서 입력한 SELET-OPTIONS를 Function Module에서 사용할 수 있을까?

화면의 SELECT-OPTIONS에 사용된 타입은 CHAR 40짜리 타입이다.

SELECT-OPTIONS로 선언한 변수의 타입을 보면

SIGN, OPTION은 공통이고

사용하는 필드의 타입에 맞춰 C(40)으로 맞춰진것을 보인다.

만약 타입이 CHAR 45라면 C(45)로 구성된다.

우리는 SIGN, OPTION과 타입을 맞춘 LOW, HIGH를 구성하여

Function Module에 던져주면 SELET-OPTIONS를 사용할 수 있다.

1. SIGN, OPTION, LOW, HIGH 구성한 구조체 만들기

2. SELET-OPTIONS에 담긴값 구조체로 옮기기

SELET-OPTIONS와 동일한 필드로 구성된 변수를 선언한다.

SELET-OPTIONS 변수인 S_MATNR에 들어 있는 값을

우리가 만든 구조체로 구성된 Internal Table에 옮긴다.

3. Function Module에서는 SELET-OPTIONS와 동일한 필드로 구성된 TABLE 타입으로 받기

Function Module에서는 SELET-OPTIONS에 들어있는 값을

우리가 만든 SELET-OPTIONS와 동일한 타입을 받아 사용하면 된다.

꼭 Tables에 사용하지 않아도 된다.

Tables에 선언하면 Header Line까지 자동으로 구성 된다는 장점이 있다.

Export 파라미터에 SELET-OPTIONS를 Table 형식으로 만든 타입을 사용해도 된다.

SELET 쿼리에 SELET-OPTIONS와 동일하게 IN 구문을 사용할 수 있으며

LOOP.문에서도 사용 가능하다.

결론

SELET 쿼리에 다양한 조건을 담아 사용하는 IN 키워드는

SELET-OPTIONS만 사용 가능한 키워드가 아니였다.

SELET-OPTIONS와 동일한 구조로 Internal Table이 존재한다면

SELET-OPTIONS처럼 사용할 수 있다.

+ 보너스 퀴즈

SELECT 쿼리에 SELET-OPTIONS를 사용했다.

자재 11과 12 사이

이것이 SELET-OPTIONS에 들어왔다.

이때의 결과는

11과 12 자재가 나온다.

SELET-OPTIONS에 Not Equal로 자재 13을 넣으면 결과는 어떻게 나올까?

자재 11과 자재 12에 자재 13과 일치하지 않은 조건을 추가했으니

원래 결과대로 자재 11과 자재 12만 나올까?

아니다.

조건은 OR로 묶여서 나온다.

BT 자재11 ~ 자재12 (<= 조건과 일치하는 2개)

NE 자재 13 (<= 조건과 일치하는 183개)

두개의 OR로 묶인 데이터가 DISTINCT처럼 중복은 제거하고 들어온다.

CALL FUNCTION할때 EXCEPTIONS와 SY-SUBRC 관계

승민아 — Sat, 2 May 2026 23:21:42 +0900

아니...

EXCEPTIONS 키워드를 작성해주지 않아도

알아서 FM에서 발생한 RAISE 구문이 있다면

그에 맞는 숫자 번호로

알아서 SY-SUBRC에 담겨서 처리할 수 있을거라 생각했는데..

아니다.

EXCEPTIONS를 작성하지 않으면

해당 RAISE를 프로그램에서 처리할 구문이 준비되지 않았다고 판단하고 덤프가 발생한다…

결론

FM 호출 파라미터 EXCEPTIONS를 생략하더라도...

SY-SUBRC에 FM의 EXCEPTIONS가 들어가지 않는다...

Lock Object 사용할때 _COLLECT 파라미터 주의사항

승민아 — Wed, 29 Apr 2026 23:07:26 +0900

인트로

Lock Object를 사용해보려고

혼자 영화관 좌석 예약 프로그램을 만들어보다..

다음과 같은 이상현상을 발견했다.

첫번째 박스에는

THEATER_ID : 영화관 지점 코드

SEAT_ROW : 좌석 행 번호

SEAAT_COL : 좌석 열 번호

이렇게 입력 받은 좌석을 LOCK을 거는 코드이다.

이때 모든 좌석을 한번에 락을 걸고자 _COLLECT 파라미터를 사용했다.

_COLLECT에 모인 락 요청들은

'FLUSH_ENQUEUE' 펑션을 통해 한번에 락을 요청할 수 있다.

이때, 락 거는데 문제가 있다면 SY-SUBRC = 1을 반환한다.

그래서

두번째 박스에서는 락 에러 발생시

락 실패를 알리고 RETURN 하는 코드를 작성했다.

_COLLECT 사용시

위와 같이 작성하면 문제가 발생한다..

아.. 우선

_COLLECT는

메모리에 락 요청들을 모았다가

이 요청들을 묶어서 한번에 요청하겠다는 파라미터이다.

락을 순차적으로 걸다가 문제가 발생시

기존에 걸었던 락들도 하나하나 풀기 번거로울거 같아서

한번에 묶어서 처리하고자 _COLLECT를 사용했다.

문제 상황

락을 한번에 걸다 문제가 발생했을때

RETURN을 해버리면

기존에 문제가 되는 락 데이터가 메모리에 그대로 남아있다.

그래서

정상적으로 락을 걸 수 있는 데이터를 가지고

락을 요청하더라도

기존의 락을 걸 수 없는 데이터가 메모리에 남아있기에

성공적인 락 결과를 받을 수 없다.

위처럼

락 실패시

'RESET_ENQUEUE' 펑션을 사용해서

메모리에 남겨둔 락 요청 모음들을 비워주자.

요청한 락들을 푸는

‘DEQUEUE_ALL’ 이라는 펑션도 있는데

이건 폭탄과도 같다고한다.(재미나이 피셜)

모든 락을 풀어버린다고하는데 어떤 기준으로 풀어버리는지 모르겠다.

그래서 상세하게 찝어서 DEQUEUE 날려주기.

LOOP문 내에서 Internal Table MODIFY TABLE과 MODIFY 차이

승민아 — Wed, 15 Apr 2026 23:40:02 +0900

MODIFY 구문을 잘 사용안해서 그런가...

한번 정리해서 기억해두려고 작성한다.

Internal Table을 도는 LOOP문 내에서

MODIFY TABLE과 MODIFY가 어떻게 다르게 동작하는지 보자.

예시 코드

GT_DATA의 키값은 CHAR형 필드가 ID밖에 없으므로

ID가 키값이 된다.

첫번째와 두번째 데이터의 키값이 겹치는 상황.

이때 두번째 데이터에 대해 MODIFY 구문이 발생했을때

MODIFY TABLE과 MODIFY는 어떻게 동작할까?

결과적으로는

MODIFY TABLE 구문은 Work Area에 들어있는 키값으로

Internal Table에서 일치하는 데이터를 찾아 수정을하고

MODIFY 구문은 루프 문에서의 SY-TABIX 값으로

해당 인덱스 데이터를 Work Area에 들어있는 값으로 바로 수정한다.

MODIFY TABLE일때 결과

두번째 ROW 데이터에서 MODIFY가 일어났지만

GT_DATA의 첫번째 ROW에서 FROM절에 명시한 구조체와 키값이 일치하므로

이 첫번째 데이터만을 MODIFY해버린다.

MODIFY 일때 결과

인덱스 기반으로 처리하므로 2번째 인덱스 데이터를 접근할때 MODIFY했으므로

2번째 데이터의 값을 MODIFY 한다.

+ MODIFY 구문을 이용해 조건을 가지고 특정 필드 값을 바꿀 수 도 있다.

[ABAP] RTTS (RunTime Type Service)

승민아 — Sun, 15 Mar 2026 01:29:11 +0900

RTTS

RTTS는 RunTime Type Service이다.

프로그램 실행중에 데이터의 타입 정보를 얻거나, 데이터의 타입을 동적으로 생성을 돕는 클래스이다.

RTTS로 RTTI와 RTTC가 있다.

1. RTTI (RunTime Type Identification) - 타입 정보 얻기

이미 존재하는 데이터를 가지고 타입 정보를 얻는다.

2. RTTC (RunTime Type Creation) - 타입 생성

프로그램 실행 도중에 사전에 정의하지 않은 새로운 타입을 생성함.

그냥 타입 추론과 생성 기능이 있다고 간단하게 생각하자~

CL_ABAP_TYPEDESCR 클래스를 사용하는데

위의 구조를 갖는다.

예제 코드

DESCRIBE_BY_DATA

변수 GT_DATA와 GS_DATA를 사용했을때 차이를 보자.

1. GT_DATA 변수

GO_TYPEDESCR 변수에 여러 필드가 존재하지만 CL_ABAP_TYPEDESCR 필드에 값을 보면

타입 종류 KIND에 T가 들어가 있고

T는 KIND_TABLE 테이블 타입임을 알 수 있다.

TYPE_KIND도 타입을 표현하는거 같은데

TYPE_KIND와 KIND 두개의 차이를 모르겠다 ㅎㅎ.

GO_TYPEDESCR 변수에 담긴 필드를 조금 더 내려보자.

CL_ABAP_TABLEDESCR 필드에 값이 담겨있다.

다른 STRUCT나 COMPLEXDESCR 필드도 아닌

CL_ABAP_TABLEDESCR 필드에 값이 들어있다.

왜냐. 값의 타입이 T라고 테이블 타입이라고 했으니

정보들이 CL_ABAP_TABLEDESCR 필드에 담겨 있는 것이다.

만약 구조체 타입이였다면 CL_ABAP_STRUCTDESCR 필드에 값이 들어 있을 것이다.

KEY 필드에는 이 테이블 타입이 어떤 필드를 키 값으로 구성되었는지도 알 수 있다.

2. GS_DATA 변수

GS_DATA 변수의 타입은 STRUCTURE 타입이다.

그래서 CL_ABAP_STRUCTDESCR에 값이 들어 있다.

이 구조체에 구성된 필드들도 COMPONENTS를 통해 알 수 있다.

계층 구조

자 이제 처음에 보여준 계층 구조에 대해 정리해보자.

GO_TYPEDESCR 변수는 CL_ABAP_TYPEDESCR 타입이다.

이 변수에 CL_ABAP_TYPEDESCR, CL_ABAP_TABLEDESCR, …, CL_ABAP_STRUCTDESCR 변수가 존재한다.

위의 계층 구조가 포함되어 있는 것이다.

우린 이제 테이블 정보냐 구조체 정보냐에 따라 CL_ABAP_TABLEDESCR, CL_ABAPSTRUCTDESC 변수에

담아서 필요한 메소드와 정보들을 사용하면 되는것이다.

변수에 담을때 다운캐스팅인지, 업캐스팅인지에 따라 = 또는 ?=를 사용한다.

DESCRIBE_BY_NAME

예제 코드에서는 DESCRIBE_BY_DATA로 이미 존재하는 데이터 오브젝트를 가지고 정보들을 뽑아냈다.

하지만 DESCRIBE_BY_NAME을 사용하면

로컬로 선언된 타입이나, DDIC에 선언된 STRUCTURE로 타입 정보들을 뽑아낼 수 있다.

다음 사진들은

DESCRIBE_BY_NAME( ‘TY_TYPE’ ).으로 호출했을때의 결과이다.

로컬로 선언한 'TY_TYPE' 타입은 구조체 타입임을 확인할 수 있다.

구조체 타입이므로 CL_ABAP_STRUCTDESC 필드에 정보가 담겨져 있다.

DDIC에 정의된 Deep Structure 타입도 다음과 같이 읽을 수 있다.

계층 구조를 이용해서 자유자재로 타입 변환을 해가며

타입 정보들을 얻을 수 있다.

입력 받은 DDIC Structure 이름으로 Internal Table 만들어보기

<GT_TABLE>에는 입력 받은 테이블명으로 Internal Table을 구성할 수 있다.

COMPONENTS로 구조체를 만들 수 있고

이 구조체로 또 TABLE 타입을 만들 수 있다.

이 TABLE 타입으로 동적 Internal Table을 만들 수 있다.

동적으로 만든 Internal Table에 Work Area를 어떻게 만들고

APPEND 할 수 있을까?

응용 - 필드 추가하고 삭제하기

응용해서 컴포넌트를가지고 Internal Table을 만드는 코드 중간에

컴포넌트들을 추가하건 삭제해서 Internal Table을 새롭게 구성할 수도 있다.

예를 들어 셀 색깔을 위한 'LVC_T_SCOL' 타입의 필드를 추가한다면

위와 같이 DDIC에 존재하는 'LVC_T_SCOL'이므로

DESCRIBE_BY_NAME을 통해서 추가할 수 있다.

값은 다음과 같이 접근해서 넣었다.

필드 카탈로그 만들기

테이블명을 한개 입력 받았을때

동적 Internal Table을 구성하고 필드 카탈로그를 만드는 로직이다.

복잡한 구조는 아니고 단 하나의 테이블일때만 이렇게 만들어봤는데

방법 1

방법 2

COMPONENTS들로 STRUCTURE를 만들었다면

그 구조를 READ_STRUCTDESC에 넘겨 필드 카탈로그를 뽑아낼 수 있다.

GO_STRUCTDESCR에 'LVC_T_SCOL'가 포함되어있지만

알아서 제외해준다.

셀 스타일 LVC_T_STYL

마찬가지로 LVC_T_STYL 컴포넌트를 끼워 넣고

동적 Internal Table을 생성하면 된다.

값 설정은 위와 같이 했다.

CREATE_DYNAMIC_TABLE과 LVC_T_SCOL

승민아 — Thu, 12 Mar 2026 22:50:15 +0900

CREATE_DYNAMIC_TABLE 펑션을 사용하면

필드 카탈로그를 넘겨주어 그에 맞는 Internal Table을 뽑아낼 수 있다.

이것으로 동적 ALV를 만들었다.

(참고로 필드 카탈로그 타입 안지정해서 넣으면 기본값은 C(11)로 컬럼이 만들어짐)

그런데 셀 색깔을 위해서 Internal Table에 LVC_T_SCOL 타입의 필드가 필요하다.

어떻게 Internal Table에 LVC_T_SCOL 필드를 넣을 수 있을까?

필드 카탈로그로 <GT_BOOK> 테이블을 만드는 과정은 그대로이다.

다음 과정을 거쳐서 필드 카탈로그를 추가해주면 된다.

DDIC에 LVC_T_SCOL 타입의 필드를 갖는 구조체를 만든다.

필드 카탈로그는 위와 같이 구성한다.

TECH 값을 꼭 주도록하자.

기술적 필드로 사용하겠다는 표시이다.

REF_TABLE : 구조체 만들었을때 그 이름

REF_FIELD : 구조체에 추가한 LVC_T_SCOL 타입의 필드명

그러면 <GT_BOOK>에 Internal Table 필드가 하나 추가된것을 확인할 수 있다.

CTAB은 Structure: deep 타입이다.

구성을 보면 셀 타입을 넣기위해 필요한 LVC_T_SCOL 타입인것을 확인할 수 있다.

그러면 필드 심볼 테이블인 <GT_BOOK>에

LVC_T_SCOL 필드에는 어떻게 접근하고 값을 넣어줄까?

일반 필드들은 다음과 같이 동적으로 생성된 테이블 구조에 맞는 WorkArea를 만들어서 넣었다.

LVC_T_SCOL 필드에는?

다양한 방법이 있지만

다음 방법이 간단하다..

LVC_T_SCOL의 라인 타입인 LVC_S_SCOL을 선언

필드심볼로 인터널 테이블인 <GT_BOOK>에 대한 WorkArea(<FS_WA>)를 가져오고

이 WorkArea가 갖는 셀 색깔을 위한 LVC_T_SCOL 타입의 필드를 <FS_CTAB_ITAB>에 할당할 계획이다.

위 사진처럼 LVC_S_SCOL 타입의 필드 값을 가져오고

값을 할당하고 <FS_CTAB_ITAB>에 APPEND 해주자.

IF <FS_CTAB_ITAB> IS ASSIGNED 보단

SY-SUBRC = 0이 좋을듯하다.

[ABAP] HTML로 누적 막대 그래프 그려 넣기

승민아 — Fri, 27 Feb 2026 16:17:44 +0900

ABAP에서 누적 막대 그래프 그리기를 포기했었는데

어느날 회식때 동료분이 블로그 글 보고 기억난다고 알려주셔서 그리는 방법을 알게 되었다.

정말 감사합니다.

기존 코드를 가지고 쉬운 내용으로 템플릿을 만들어 봤다.

A, B, C, D 제품이 있을때

월별 누적 막대그래프를 예제이다.

방법은

누적 막대 그래프 차트를 그려주는 펑션을 가지고 이미지 데이터를 만들고

이미지 데이터를 가지고 이미지 URL을 생성하고

이미지 URL을 HTML에 포함시켜 SAP GUI에 출력하는 방식이다.

막대 그래프, 도넛 그래프 등 다양한 그래프를 그릴 수 있다.

코드중에 HTML을 어디 화면에 뿌려줄지 지정할 수 있다.

위처럼 ALV 컨테이너가 없어도 화면에 뿌려줄 수 있지만

컨테이너를 지정해서 해당 ALV에 표시할 수 도 있다.

HTML과 IGS_CHART를 TOP에 선언하여 전역적으로 해주고

위처럼 ALV INIT 이후에

HTML의 부모를 원하는 컨테이너에 넣어주면 된다.

HTML로 그린 화면은 다른 ALV로 전환하더라도 HTML에 가려져 안보일 수 있으니

VISIBLE을 껐다켰다하면서 다른 ALV와 사용해야한다.

전체 코드

*&---------------------------------------------------------------------*
*& Report ZS4H086R11
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZS4H086R11.

" 예제 : 월별 제품 판매량을 누적 막대그래프

TYPES :
  BEGIN OF TY_SALES,
    MONTH       TYPE N LENGTH 2,   " 월
    PRODUCT_ID  TYPE C LENGTH 10,  " 제품ID
    SALES_COUNT TYPE I,            " 판매량
  END OF TY_SALES.

DATA : GT_SALE_DATA TYPE TABLE OF TY_SALES.

GT_SALE_DATA = VALUE #(
  ( MONTH = 1 PRODUCT_ID = 'A' SALES_COUNT = 1 )
  ( MONTH = 1 PRODUCT_ID = 'B' SALES_COUNT = 2 )
  ( MONTH = 2 PRODUCT_ID = 'A' SALES_COUNT = 1 )
  ( MONTH = 2 PRODUCT_ID = 'B' SALES_COUNT = 2 )
  ( MONTH = 2 PRODUCT_ID = 'C' SALES_COUNT = 3 )
  ( MONTH = 3 PRODUCT_ID = 'D' SALES_COUNT = 4 )
).

START-OF-SELECTION.
  DATA : LT_IGS_DATA TYPE TABLE OF IGS_DATA,
         LS_IGS_DATA LIKE LINE OF LT_IGS_DATA.

  TRY.
* Default RFC-Destination für IGS (Internet Graphics Server)
      DATA(LV_RFC_DEST) = CONV CHAR32( 'IGS_RFC_DEST' ).

* RFC-Destination festlegen
      CL_GFW=>ITS_RFC_DEST = LV_RFC_DEST.

* Ist der IGS Chart interpreter erreichbar?
      IF CL_IGS_DATA=>IS_REGISTERED_TYPE( TYPE = CL_IGS_CHART=>INTERPRETER_TYPE ) = ABAP_TRUE.

* IGS Chart-Objekt erzeugen
        DATA(O_IGS_CHART) = NEW CL_IGS_CHART( ).
        O_IGS_CHART->TYPE = CL_IGS_CHART=>CO_TYPE_COLS_STACKED.
        O_IGS_CHART->WIDTH = 500. "넓이
        O_IGS_CHART->HEIGHT = 500. "높이
        O_IGS_CHART->TITLE = 'Title'. "제목
        O_IGS_CHART->TITLE_CATEGORIES = 'X axis Title'. "X축 제목
        O_IGS_CHART->TITLE_VALUES = 'Y axis Title'. "Y축 제목

        LOOP AT GT_SALE_DATA ASSIGNING FIELD-SYMBOL(<FS_SALLE_DATA>).
          LS_IGS_DATA-X = <FS_SALLE_DATA>-MONTH.
          LS_IGS_DATA-Y = <FS_SALLE_DATA>-SALES_COUNT.
          LS_IGS_DATA-GROUPID = <FS_SALLE_DATA>-PRODUCT_ID.
          APPEND LS_IGS_DATA TO LT_IGS_DATA.
          CLEAR LS_IGS_DATA.
        ENDLOOP.

        "group id 정렬 , group id 순서가 다른 경우 매핑이 되지 않아 로직 추가
*        SORT LT_IGS_DATA BY GROUPID X.
        O_IGS_CHART->DATA = LT_IGS_DATA.
*        O_IGS_CHART->EXTENSION = VALUE IGS_EXT_TAB(
*                                                    ( TOKEN = 'TITLE' VALUE = '')"'href="http://www.google.de"' )
*                                                    ( TOKEN = 'LGNDI' VALUE = '')"'href="http://www.google.de"' )
*                                                  ).

        DATA: LV_CONTENT_TYPE TYPE W3PARAM-CONT_TYPE.
        DATA: LV_CONTENT_SUBTYPE TYPE W3PARAM-CONT_TYPE.
        DATA: LV_CONTENT_LENGTH TYPE W3PARAM-CONT_LEN.
        DATA: IT_MIME_CONTENT TYPE W3MIMETABTYPE.
        DATA: IT_IMAGEMAP_HTML TYPE W3HTMLTABTYPE.
        DATA: LV_MSG TYPE CHAR255.

*       Chart 데이터를 가지고 image 데이터 생성
        O_IGS_CHART->SEND( IMPORTING
                             CONTENT_TYPE   = LV_CONTENT_TYPE
                             CONTENT_LENGTH = LV_CONTENT_LENGTH
                             CONTENT        = IT_MIME_CONTENT
                             IMAGEMAP       = IT_IMAGEMAP_HTML
                             MSG_TEXT       = LV_MSG ).

* CONTENT TYPE : image/* -> CONTENTTYPE : image, CONTENT_SUBTYPE : *
        SPLIT LV_CONTENT_TYPE AT '/' INTO LV_CONTENT_TYPE LV_CONTENT_SUBTYPE.

* HTML-Viewer erzeugen
        DATA(O_HTML) = NEW CL_GUI_HTML_VIEWER( PARENT = CL_GUI_CONTAINER=>DEFAULT_SCREEN ).

        DATA: LV_MIME_CONTENT_URL TYPE W3URL.

* image 데이터를 가지고 이미지 URL을 생성
        O_HTML->LOAD_DATA( EXPORTING
                             TYPE         = LV_CONTENT_TYPE
                             SUBTYPE      = LV_CONTENT_SUBTYPE
                             SIZE         = LV_CONTENT_LENGTH
                           IMPORTING
                             ASSIGNED_URL = LV_MIME_CONTENT_URL
                           CHANGING
                             DATA_TABLE   = IT_MIME_CONTENT ).

* 위에서 생성된 이미지 URL을 img 태그의 src 파라미터로 사용하여 HTML 구성
        DATA(IT_HTML) = VALUE W3HTMLTABTYPE( ( LINE = '<html>' )
                                             ( LINE = '  <head>' )
*                                             ( line = '    <meta charset="utf-8">' ) "AAA
                                             ( LINE = '    <title>IGS Chart Demo</title>' )
                                             ( LINE = '  </head>' )
                                             ( LINE = '  <body>' ) ).
        APPEND LINES OF VALUE W3HTMLTABTYPE( ( LINE = '    <img src="' && LV_MIME_CONTENT_URL && '" usemap=#chart border=0>' )
                                             ( LINE = '  </body>' )
                                             ( LINE = '</html>' ) ) TO IT_HTML.

        DATA: LV_OUTPUT_URL TYPE W3URL.

* 위의 HTML을 가지고 HTML URL을 생성
        O_HTML->LOAD_DATA( EXPORTING
                             TYPE         = 'text'
                             SUBTYPE      = 'html'
                           IMPORTING
                             ASSIGNED_URL = LV_OUTPUT_URL
                           CHANGING
                             DATA_TABLE   = IT_HTML ).

* HTML im HTML-Viewer anhand der URL anzeigen : HTML URL을 사용하여 HTML 출력
        O_HTML->SHOW_URL( URL = LV_OUTPUT_URL ).
*        O_HTML->SHOW_URL( URL = 'https://www.naver.com/' ). <- 브라우저처럼 다른 웹 URL에 접속도 가능하다.

* Container cl_gui_container=>default_screen erzwingen
        WRITE: / SPACE.
      ENDIF.
    CATCH CX_ROOT INTO DATA(E_TXT).
      WRITE: / E_TXT->GET_TEXT( ).
  ENDTRY.

[ABAP] CREATE DATA, 동적 Internal Table에 Insert하기

승민아 — Fri, 9 Jan 2026 00:00:09 +0900

https://non-stop.tistory.com/870

지난 포스팅에서 동적 ALV 필드를 구성하는 코드 중에

ASSIGN COMPONENT하는 부분 CREAT DATA에 대해서 모르겠어서

이해할 수 있도록 단계적 필요 개념과 결과코드를 정리해 보았다.

CREATE DATA

변수를 참조하는 오브젝트를 생성하는 구문이다.

@DREF→* (역참조라고 부름) : CREATE DATA로 메모리 위치가 할당되면 그 값을 DREF가 갖게 된다. *로 가리키는 그 메모리 위치를 INTO절에 작성해서 결과를 받는 것이다.

DREF→필드명 : DFEF를 참조하여 값을 꺼냄

[TYPE|LIKE DTYPE]으로 타입을 지정하는 경우 자동으로 타입 변환된다.

예를 들어보자면

ANY 타입으로 선언했지만 SCARR 타입으로 지정할 수 있다.

필드 심볼 생성과 ASSIGN하는 법

CREATE DATA하고 필드 심볼에 할당하는 법

왜 데이터 참조(Data Reference)를 사용할때 필드 심볼을 사용하는 과정을

거쳐야하는지 몰랐었는데

다음과 같이 데이터 참조 변수를 동적으로 Generic Type으로 생성했을때

DATA dref TYPE REF TO DATA.
CREATE DATA dref TYPE ('PERSON').

dref->name = '홍길동'.

구조체의 필드에 접근하면 에러 메시지가 발생한다.

"This generic reference cannot be dereferenced (->) at the current statement position."

그래서 타입이 정해지지 않은 데이터 참조 변수는 필드 심볼을 활용해야한다.

동적 ITAB에 WA 만들어 Insert 하기

동적으로 구성된 Internal Table과

그 Internal Table의 WA를 만들어 Internal Table에 넣는 방법을 이제

이해할 수 있을 것이다.

[ABAP] 동적 ALV 필드 구성 및 월별 주차 계산하기

승민아 — Sat, 3 Jan 2026 15:58:36 +0900

사실 저번에 동적 ALV Field Catalog를 구성하는 방법에 대해

작성한 적 있지만.

깔끔하게 다시 이해하고자 다시 만들어 봤다.

목표

입력한 연도에 맞춰서

일자별을 누르면 해당 연도의 모든 일자별 ALV 필드가 나오고

주차별을 누르면 월별 주차와 함께 기간을 표시해 보자.

월별 주차 계산에 좀 어려웠는데

2025년 2026년은 월별 주차가 잘 계산되어 나오는 걸 확인했다.

동적으로 만든 ALV에 고정된 필드도 추가해 보고 데이터도 집어넣어보자.

일자에 맞는 주차에도 표시하자.

TOP Include

<GT_DYNAMIC> 필드 심볼에는 구성된 Field Catalog를 통해서

Internal Table을 만드는 펑션을 이용해 Internal Table을 가리킬 것이다.

ALV 초기화

ALV 관련 변수들의 초기화에도 다를 건 없다.

나는 필드 카탈로그를 구성하고 Display 하는 펑션 호출하는 부분은

버튼이 클릭했을 때 동작하도록 구성했기에

하단의 ALV 초기화 단계에서는 박스 친 저 부분만 구성했다.

일자별, 주차별 클릭 이벤트

CREATE_DAY_FCAT

동적 ALV라고 해서 특별히 다른 건 없다.

원하는 형식으로 필드 카탈로그를 구성해 주면 된다.

코드

FORM CREATE_DAY_FCAT .

  DATA : LS_FCAT     TYPE LVC_S_FCAT,
         LV_LAST_DAY TYPE SY-DATUM,   " YYYYMMDD 형식으로 입력된 연도 월의 말일이 포함된 풀형식 날짜
         LV_MONTH    TYPE N LENGTH 2, " MM월 - YYYMMDD에서 추출
         LV_DAY      TYPE N LENGTH 2. " DD일 - YYYMMDD에서 추출

  REFRESH GT_DYNAMIC_FCAT.

  DO 12 TIMES.

    CALL FUNCTION 'RP_LAST_DAY_OF_MONTHS'
      EXPORTING
        DAY_IN            = CONV SY-DATUM( |{ P_YEAR }{ SY-INDEX WIDTH = 2 ALIGN = RIGHT PAD = '0' }01| )  " 'P_YEAR년X월01일'를 넘겨주고
      IMPORTING
        LAST_DAY_OF_MONTH = LV_LAST_DAY. " 'P_YEAR년X월XX일' 풀형식의 말일을 받는다

    LV_DAY = LV_LAST_DAY+6(2).   " YYYYMMDD 형식에서 DD만 추출 (말일 추출)
    LV_MONTH = LV_LAST_DAY+4(2). " MM만 추출
    DO LV_DAY TIMES.
      CLEAR LS_FCAT.
      LS_FCAT-FIELDNAME = |{ LV_LAST_DAY+0(6) }{ SY-INDEX WIDTH = 2 ALIGN = RIGHT PAD = '0' }|. " YYYYMM01부터 해당 월의 말일까지 필드네임 할당
      LS_FCAT-COLTEXT = |{ CONV I( LV_LAST_DAY+4(2) ) }/{ SY-INDEX }|. " MM/DD 형식
      APPEND LS_FCAT TO GT_DYNAMIC_FCAT.
    ENDDO.

  ENDDO.

* 현재는 ALV 필드를 TABLE에 존재하는 필드로 구성하는게 아니라서 안했지만. TABLE에 존재하는 타입의 필드로 ALV를 구성하고자한다면
* 아래의 펑션을 이용해 더 심화된 코드를 작성해야한다.
* 'NAMETAB_GET' 펑션으로 TABLE의 필드정보를 가져와서 FCAT을 완전히 REF_TABLE, REF_FIELD 등 온전한 필드타입 구성을 통해
*  ALV화면에서 필드 우클릭하여 정렬등을 했을때 안정성있게 동작할 수 있게 가능.
* 'DDIF_FIELDINFO_GET' 펑션을 사용해서 테이블의 필드 타입을 가져올 수도 있음.

ENDFORM.

CREATE_FCAT_TO_ITAB

'CL_ALV_TABLE_CREATE=>CREATE_DYNAMIC_TABLE' 펑션을 사용하여

설정한 FieldCatalog를 가지고 적절한 Internal Table을 반환받을 수 있다.

Field Catalog와 데이터를 뿌려줄 Internal Table이 구성되었으니

ALV를 Display 할 수 있는 것이다.

코드

FORM CREATE_FCAT_TO_ITAB .

* CALL METHOD CL_ALV_TABLE_CREATE=>CREATE_DYNAMIC_TABLE 메소드를 사용하여 필드카탈로그를 통해
* 바로 internal Table을 생성할 수도 있다.

  DATA : LP_TABLE TYPE REF TO DATA. " 메소드 호출 결과 받을 Pointer

  UNASSIGN <GT_DYNAMIC>.

  CALL METHOD CL_ALV_TABLE_CREATE=>CREATE_DYNAMIC_TABLE
    EXPORTING
      IT_FIELDCATALOG = GT_DYNAMIC_FCAT                  " Field Catalog
    IMPORTING
      EP_TABLE        = LP_TABLE.

  ASSIGN LP_TABLE->* TO <GT_DYNAMIC>. " LT_TABLE은 주소만 가진 변수라 LOOP를 사용할 수 없다. 그래서 ASSIGN으로 필드심볼과 연결하는 것이다.

  GS_DYNAMIC_LAYOUT-CWIDTH_OPT = 'A'.
  CALL METHOD GO_DYNAMIC_ALV_GRID->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      IS_LAYOUT       = GS_DYNAMIC_LAYOUT
    CHANGING
      IT_OUTTAB       = <GT_DYNAMIC>
      IT_FIELDCATALOG = GT_DYNAMIC_FCAT.
ENDFORM.

CREATE_WEEK_FCAT

주석으로 설명을 열심히 적어 놨기에 월별 주차를 구하는 핵심 알고리즘만 설명하자면

'월~일' 이것이 하나의 주차이다.

이 주차의 요일들이 하나의 달에 모두 포함되어 있으면

그 주차는 해당 달의 주차이지만

'월~일' 요일이 다른 두개의 달로 찢어져 들어가 있다면 주차의 계산을 생각해봐야 한다.

더 많은 요일을 갖는 쪽이 해당 주차를 가져간다.

즉, 목요일을 갖는 달이 해당 주차의 주인인 것이다.

내가 생각한 알고리즘이 모든 연도에 잘 나올지 모르겠지만

2015 2016년은 원하는 대로 잘 나오는 것을 확인했다.

코드

FORM CREATE_WEEK_FCAT .

  DATA : LS_FCAT           TYPE LVC_S_FCAT,
         LV_WEEK           TYPE SCAL-WEEK,  " YYYYWW 형식의 주차
         LV_START_WEEK_MON TYPE SY-DATUM,   " YYYYWW 주차의 월요일 날짜
         LV_END_WEEK_DAY   TYPE SY-DATUM,   " YYYYWW 주차의 일요일 날짜
         LV_STACKED_WEEK   TYPE I, " 누적 주차 변수. 월별 최대 주차를 구하기 위해 누적 계산용 변수. 1월 1 2 3주차 2월 1 2 3 4주차 3월 1 ... 이렇게 월이 바뀔때까지 주차 누적
         LV_STACKED_MONTH  TYPE I. " 위 누적 주차변수에 월을 담당하는 변수.
  REFRESH GT_DYNAMIC_FCAT.

  " 각 월의 몇주차가 존재하는지 계산하여 필드 카탈로그 설정
  LV_STACKED_MONTH = 1. " 1월
  LV_STACKED_WEEK = 1.  " 1주차부터 계산 시작
  DO.
    LV_WEEK = |{ P_YEAR }{ SY-INDEX WIDTH = 2 ALIGN = RIGHT PAD = '0' }|. " YYYY WW 형식에 WW를 SY-INDEX 2자리로 구성

    " YYYYWW를 넣어 LV_WEEK 주차의 시작 월요일 날짜(LV_START_WEEK_MON)를 받음
    CALL FUNCTION 'WEEK_GET_FIRST_DAY'
      EXPORTING
        WEEK         = LV_WEEK
      IMPORTING
        DATE         = LV_START_WEEK_MON
      EXCEPTIONS
        WEEK_INVALID = 1
        OTHERS       = 2.
    IF SY-SUBRC <> 0.
      EXIT.
    ENDIF.

    CALL FUNCTION 'GET_WEEK_INFO_BASED_ON_DATE'
      EXPORTING
        DATE   = LV_START_WEEK_MON
      IMPORTING
        SUNDAY = LV_END_WEEK_DAY.

    " 월~일이 다른 달로 찢어졌을때 그 주는 누가 갖는지. 소유권의 핵심은 목요일을 어떤 달이 가져가는 것이다.
    " 목요일을 갖는 달이 해당 주차를 가져간다.
    " 즉, 월요일에서 3일을 더하면 목요일이된다. 이 목요일이 어떤 달에 속해있는지 보면 해당 주차는 누구의 달인지 정할 수 있다.
    " 월~일이 안찢어지는경우는 월~일이 하나의 월에 포함될때이다.
    " YYYYWW 주차를 넣었을때 현재 월(LV_STACKED_MONTH)과 일치하면 해당 월의 주차로 확정 지어 할당할 수 있다.
    DATA : LV_ADD_RESULT TYPE SY-DATUM.
    LV_ADD_RESULT = LV_START_WEEK_MON + 3.

    " 주차 확정 : 월요일과 일요일의 월이 일치할때
    IF LV_START_WEEK_MON+4(2) = LV_STACKED_MONTH AND LV_END_WEEK_DAY+4(2) = LV_STACKED_MONTH.
      LS_FCAT-FIELDNAME = LV_WEEK.
      LS_FCAT-COLTEXT = |{ P_YEAR+2(2) }-{ LV_STACKED_MONTH WIDTH = 2 ALIGN = RIGHT PAD = '0' }-{ LV_STACKED_WEEK }W({ LV_START_WEEK_MON DATE = USER }~{ LV_END_WEEK_DAY DATE = USER })|. " 26-01-1W(기간)
      APPEND LS_FCAT TO GT_DYNAMIC_FCAT.
      LV_STACKED_WEEK += 1.
    ELSE. " 다른달로 찢어져있을때(월이 일치하지 않을때) 목요일을 기준으로 해당 주차의 주인을 찾아야한다.

      IF LV_ADD_RESULT+4(2) = LV_STACKED_MONTH. " 주인이 현재 월이면 현재 주차는 현재 월의 것
        LS_FCAT-FIELDNAME = LV_WEEK.
        LS_FCAT-COLTEXT = |{ P_YEAR+2(2) }-{ LV_STACKED_MONTH WIDTH = 2 ALIGN = RIGHT PAD = '0' }-{ LV_STACKED_WEEK }W({ LV_START_WEEK_MON DATE = USER }~{ LV_END_WEEK_DAY DATE = USER })|. " 26-01-1W(기간)
        APPEND LS_FCAT TO GT_DYNAMIC_FCAT.

        " 월+1 주=1 경우도 있고 주+1만하는 경우 있음 분기쳐줘야함
        IF LV_END_WEEK_DAY+4(2) = LV_STACKED_MONTH.
          LV_STACKED_WEEK += 1.
        ELSE.
          LV_STACKED_MONTH += 1.
          LV_STACKED_WEEK = 1.
        ENDIF.

      ELSE. " 현재 주차는 다음 달의 소유이다.
        LV_STACKED_MONTH += 1.
        LV_STACKED_WEEK = 1.
        LS_FCAT-FIELDNAME = LV_WEEK.
        LS_FCAT-COLTEXT = |{ P_YEAR+2(2) }-{ LV_STACKED_MONTH WIDTH = 2 ALIGN = RIGHT PAD = '0' }-{ LV_STACKED_WEEK }W({ LV_START_WEEK_MON DATE = USER }~{ LV_END_WEEK_DAY DATE = USER })|. " 26-01-1W(기간)
        APPEND LS_FCAT TO GT_DYNAMIC_FCAT.
        LV_STACKED_WEEK += 1. " 다음 주차 할당을 위해 +1
      ENDIF.

    ENDIF.

  ENDDO.

ENDFORM.

고정된 ALV 필드 추가

PO 번호와 날짜가 ALV의 어디 일자에, 어디 주차에 포함되는지 확인하기 위해

고정된 ALV 필드를 위와같이 추가하면 된다.

꼭 동적인 ALV 필드만 구성할 수 있는 것은 아니다.

필드 심볼인 Internal Table에 데이터 넣기

단계별로 작성하다 보니 꼬였는데

일자별 모드일 때 'CREATE_FCAT_TO_ITAB_DAY'

주차별일 때 'CREATE_FCAT_TO_ITAB_WEEK'를 호출하도록 변경했다.

CREATE_FCAT_TO_ITAB_DAY (데이터 넣기)

=> 빨간 박스 이전에 <GT_DYNAMIC>은 데이터를 담을 Internal Table을 생성한 것 이고

빨간박스의 ASSIGN LP_DYNAMIC->* TO <FS_DYNAMIC>은

<FS_DYNAMIC>에 Work Area 변수를 할당하는 과정이다.

위처럼 'EBELN', 'BEDAT' 고정 필드는 저렇게 할당했고

BEDAT 일자에 맞는 곳에 O 표시하는 코드를 작성해 봤다.

FIELDNAME을 YYYYMMDD 형식으로 설정했으므로

YYYYMMDD 필드에 'O' 값을 넣어주면 된다.

CREAT DATA, DATA REFERENCE 뭔지 모르겠다. 공부할게 또 생겼다..

결과가 잘 나온다.

CREATE_FCAT_TO_ITAB_WEEK

날짜를 넣어 반환되는 주차에 일치하는 곳에 'O' 표시를 하도록 했다.

ASSIGN COMPONENT하는 부분 CREAT DATA에 대해서 모르겠어서 공부해 봐야겠다.

[ABAP] XML로 그래프 커스터마이징하여 그리기

승민아 — Sun, 28 Dec 2025 23:00:47 +0900

목표

막대그래프, 꺾은선 그래프를 만들어보자.
그런데 더 세밀한 커스터마이징이 가능한.

마지막에 보여주려 했는데 선공개하자면

이렇게도 막대 그래프를 겹쳐서 그릴 수 있다.
다양하게 설정할 수 있는 값들이 많다.

잡담

CL_GUI_CUSTOM_CONTAINER와 CL_GUI_CONTAINER
타입에 대해 많이 헷갈려서

Split Container를 이용해 CHART ENGINE으로 그래프를 그리는 부분에서
CL_GUI_CUSTOM_CONTAINER과 CL_GUI_CONTAINER
를 사용하는 타입이 각각 다를 때
어떻게 막 변환하고 업캐스트하고 해야 하나 싶었는데

다음과 같이 정리하니깐 쉽게 CHART ENGINE을 사용할 수 있었다.

CL_GUI_CUSTOM_CONTAINER는
Screen Painter에서 직접 그린 Custom Control 영역에 연결하는 클래스이고

CL_GUI_CONTAINER는 이미 Split Container를 생성할 때
CL_GUI_CONTAINER 타입으로 생성되어 있는 Container이다.
GET_CONTAINER를 통해 받아와서 CHART ENGINE의 부모로 사용하면 되었다.

위 사진처럼 말이다.

주저리주저리 했는데
즉, CL_GUI_CONTAINER로 차트를 그려 넣을 수 있다.

1. 기본 환경 세팅

우선 위의 화면처럼 기본 그래프가 출력되는 환경을 맞춰보자.
그리고 누적 막대 그래프를 그려볼 것이다.

TOP Include

이전의 ALV 사진에
Split Container로 찢어진 2개의 영역 중
하단의 그래프 영역에 사용되는 변수는 빨간색으로 표시한 3개가 사용된다.

ALV Init

두 번째 영역에 CHART_CONTAINER과 CHART_ENGINE를 세팅한다.

이까지하면 다음과 같이 기본으로 표시되는 차트가 잘 나온다.

2. GRAPHICS_GUI_CE_DEMO

'GRAPHICS_GUI_CE_DEMO' 스탠다드 프로그램을 사용해서
원하는 차트를 만들어보자.
여기서 세밀한 커스터마이징이 가능하다는 것이다.

원하는 형태로 수정하여 차트 디자인을 구성하고 파일을 생성하면 된다.

위의 형태로 XML 파일을 생성했다.

위처럼 내용이 구성된 파일이다.
우리가 필요한 부분은 <SAPChart~> 머시기 부분이다.

3. STRANS

T-Code : STRANS
에 들어간다.

Create 클릭

엔터

<tt:template> 여는 태그와 </tt:template> 닫는 태그 사이에
GRAPHICS_GUI_CE_DEMO 프로그램으로 생성된 xml 내용들을 넣는다.

<SAPChart~> 머시기 부분을 저 부분에 넣어주면 된다.
내가 만든 커스터마이징 디자인으로 틀을 사용하겠다한 것이다.

4. ABAP 코드

저 틀에 사용되는 데이터는 ChartData 태그로 구성된다.
ChartData 태그에 포함되는
ChartData, Categories, Category, Series, Point, Value의 형태를 먼저 이해하고 코드를 보자.

위의 형태로 ChartData가 구성된다면

이렇게 차트가 구성된다.
차트에 들어가는 카테고리, 시리즈, 제목 등
동적으로 구성하거나 반복문을 통해 값을 넣는 방법도 존재하니 참고 링크를 보자.

이제 ChartData 태그의 형식을 이해했으면 이것을
ABAP 코드로 구성해서 데이터를 세팅해 주면 된다.

전체 코드

FORM SHOW_DAY_GRAPH .

* 1. XML로 Chart Engine 세팅
  DATA : LV_XML TYPE XSTRING.
  CALL TRANSFORMATION ZSIMPLE_CHART_CUST_086
       SOURCE ROOT = SPACE " ST의 <tt:root name="ROOT"/>와 매핑
       RESULT XML LV_XML.
  GO_CHART_ENGINE->SET_CUSTOMIZING( XDATA = LV_XML ).

* 2. 데이터 세팅 - Dummy 데이터 넣기
  DATA: LO_IXML           TYPE REF TO IF_IXML,
        LO_DOC            TYPE REF TO IF_IXML_DOCUMENT,
        LO_ROOT           TYPE REF TO IF_IXML_ELEMENT,
        LO_CATEGORIES     TYPE REF TO IF_IXML_ELEMENT,
        LO_CATEGORY       TYPE REF TO IF_IXML_ELEMENT,
        LO_LOCAL_SERIES   TYPE REF TO IF_IXML_ELEMENT,
        LO_FOREIGN_SERIES TYPE REF TO IF_IXML_ELEMENT,
        LO_POINT          TYPE REF TO IF_IXML_ELEMENT,
        LO_VALUE          TYPE REF TO IF_IXML_ELEMENT,
        LO_STREAM_FACTORY TYPE REF TO IF_IXML_STREAM_FACTORY,
        LO_OSTREAM        TYPE REF TO IF_IXML_OSTREAM,
        LO_RENDERER       TYPE REF TO IF_IXML_RENDERER,
        LV_XDATA          TYPE XSTRING.

  " 1. iXML 기본 객체 생성
  LO_IXML = CL_IXML=>CREATE( ).
  LO_DOC  = LO_IXML->CREATE_DOCUMENT( ).

  " 2. 루트 엘리먼트 <ChartData> 생성 및 추가
  LO_ROOT = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'ChartData' PARENT = LO_DOC ).

  " 3. <Categories> 영역 생성
  LO_CATEGORIES = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Categories' PARENT = LO_ROOT ).

  " 4. <Series> 영역 생성 (예: 국내매출)
  LO_LOCAL_SERIES = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Series' PARENT = LO_ROOT ).
  LO_LOCAL_SERIES->SET_ATTRIBUTE( NAME = 'label' VALUE = '국내매출' ).

  " 4. <Series> 영역 생성 (예: 해외매출)
  LO_FOREIGN_SERIES = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Series' PARENT = LO_ROOT ).
  LO_FOREIGN_SERIES->SET_ATTRIBUTE( NAME = 'label' VALUE = '해외매출' ).

  DO 12 TIMES.
    " 카테고리(X축) 값 추가
    LO_CATEGORY = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Category' PARENT = LO_CATEGORIES ).
    LO_CATEGORY->IF_IXML_NODE~SET_VALUE( SY-INDEX && '월' ).

    " Series 내부의 데이터 포인트 추가 (X월 국내매출)
    LO_POINT = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Point' PARENT = LO_LOCAL_SERIES ).
    LO_VALUE = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Value' PARENT = LO_POINT ).
    LO_VALUE->IF_IXML_NODE~SET_VALUE( |{ SY-INDEX }| ).

    " Series 내부의 데이터 포인트 추가 (X월 해외매출)
    LO_POINT = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Point' PARENT = LO_FOREIGN_SERIES ).
    LO_VALUE = LO_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Value' PARENT = LO_POINT ).
    LO_VALUE->IF_IXML_NODE~SET_VALUE( |{ 12 - SY-INDEX }| ).

  ENDDO.

  " 6. 완성된 DOM을 XSTRING으로 렌더링 (변환)
  LO_STREAM_FACTORY = LO_IXML->CREATE_STREAM_FACTORY( ).
  LO_OSTREAM = LO_STREAM_FACTORY->CREATE_OSTREAM_XSTRING( LV_XDATA ).
  LO_RENDERER = LO_IXML->CREATE_RENDERER( OSTREAM = LO_OSTREAM DOCUMENT = LO_DOC ).
  LO_RENDERER->RENDER( ).

  " 7. Chart Engine에 데이터 세팅 및 출력
  GO_CHART_ENGINE->SET_DATA( XDATA = LV_XDATA ).

  GO_CHART_ENGINE->RENDER( ).

ENDFORM.

위의 서브루틴은 클릭 시 그래프를 그리는 서브루틴이다.
위의 예제 코드로 아래의 차트가 그려진다.

내가 만든 틀에 데이터를 넣어 차트가 그려진다.

CALL TRANSFORMATION를 처음 알았는데 ABAP 코드 <-> XML 간 변환해 주는 것이다.

정말 다양하게 커스터마이징이 가능하다.

이렇게 구성할 수도 있다.

현재 차트 제목을 고정되게 템플릿 XML 안에 구성되어 있지만
참고 링크에는 동적으로 타이틀을 구성하거나 범례, 시리즈, 카테고리를 반복문을통해 넣는 방법이 존재한다.

참고 : https://community.sap.com/t5/additional-blog-posts-by-members/easy-charts-using-cl-gui-chart-engine/ba-p/13176916

보너스

싱크 때 강사님이 알려준 막대 그래프 그리는 방식을
이제 되돌아보니 이해가 간다.
순수 IXML 인터페이스? 클래스?를 사용해서 그리는 방식이었다

위 사진처럼 그려지는 코드이다.

STRANS 티코드를 사용하지 않고 순수 아밥 코드로만 막대 그래프를 그리고 싶으면 다음 코드를 참고하세요~!

TOP

* Chart
DATA: GO_CHART_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER,
      GO_CHART           TYPE REF TO CL_GUI_CHART_ENGINE.

DATA: GO_IXML          TYPE REF TO IF_IXML,
      GO_IXML_SF       TYPE REF TO IF_IXML_STREAM_FACTORY,
      GO_IXML_DATA_DOC TYPE REF TO IF_IXML_DOCUMENT,
      GO_OSTREAM       TYPE REF TO IF_IXML_OSTREAM,
      GO_ENCODING      TYPE REF TO IF_IXML_ENCODING.

그리는 코드 부분

FORM GET_BALANCE_DATA USING PV_NODE_KEY.

  DATA: LV_MONTH  TYPE N LENGTH 2.
  DATA: LS_T040 TYPE ZTFC_FIT040.

* 이월 금액, 통화
  DATA: LV_CARRYFORWARD TYPE ZTFC_FIT040-CARRYFORWARD,
        LV_WAERS        TYPE ZTFC_FIT040-WAERS.

* Grid Title
  DATA: LV_GLTXT TYPE STRING.

* 차트
  DATA: ROOT          TYPE REF TO IF_IXML_ELEMENT,
        CATEGORIES    TYPE REF TO IF_IXML_ELEMENT,
        CATEGORY      TYPE REF TO IF_IXML_ELEMENT,
        SERIES_DEBIT  TYPE REF TO IF_IXML_ELEMENT,
        SERIES_CREDIT TYPE REF TO IF_IXML_ELEMENT,
        POINT         TYPE REF TO IF_IXML_ELEMENT,
        VALUE         TYPE REF TO IF_IXML_ELEMENT,
        XDATA         TYPE XSTRING,
        DEBIT_STRING  TYPE STRING,
        CREDIT_STRING TYPE STRING.

* 선택된 계정과목코드로 계정과목명 조회
  SELECT SINGLE GLTXT
    FROM ZTFC_FIT010
    INTO LV_GLTXT
    WHERE SKANR = PV_NODE_KEY.

* ALV TItle 설정
  GS_BALANCE_LAYOUT-GRID_TITLE = '[' && LV_GLTXT && ']'.
  CALL METHOD GO_BALANCE_ALV_GRID->SET_FRONTEND_LAYOUT
    EXPORTING
      IS_LAYOUT = GS_BALANCE_LAYOUT.

  CALL METHOD GO_CHART_CONTAINER->SET_VISIBLE( EXPORTING VISIBLE = ABAP_TRUE ).

* 차트 - procesing data
  GO_IXML = CL_IXML=>CREATE( ).
  GO_IXML_SF = GO_IXML->CREATE_STREAM_FACTORY( ).

* 차트 - create an empty document and set encoding
  GO_IXML_DATA_DOC = GO_IXML->CREATE_DOCUMENT( ).
  GO_ENCODING = GO_IXML->CREATE_ENCODING(
                    BYTE_ORDER    = IF_IXML_ENCODING=>CO_LITTLE_ENDIAN
                    CHARACTER_SET = 'utf-8' ).
  GO_IXML_DATA_DOC->SET_ENCODING( GO_ENCODING ).

  ROOT        = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'ChartData' PARENT = GO_IXML_DATA_DOC ).
  CATEGORIES  = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Categories' PARENT = ROOT ).
  SERIES_DEBIT   = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Series' PARENT = ROOT ).
  SERIES_CREDIT  = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Series' PARENT = ROOT ).

  SERIES_DEBIT->SET_ATTRIBUTE( NAME = 'label' VALUE = |{ LV_GLTXT } 차변 (단위 : 원)| ).
  SERIES_CREDIT->SET_ATTRIBUTE( NAME = 'label' VALUE = |{ LV_GLTXT } 대변 (단위 : 원)| ).

  CLEAR GT_DATA.
  CLEAR GS_DATA.

* 이월 금액
  SELECT SINGLE CARRYFORWARD WAERS
    INTO (LV_CARRYFORWARD, LV_WAERS)
    FROM ZTFC_FIT040
    WHERE GJAHR = GV_YEAR
      AND SKANR = PV_NODE_KEY
      AND MON = 0.

  IF SY-SUBRC <> 0.
    LV_CARRYFORWARD = 0.
    LV_WAERS = 'KRW'.
  ENDIF.

  GS_DATA-MON = 0.
  GS_DATA-MON_TXT = '이월'.
  GS_DATA-BALANCE = LV_CARRYFORWARD.
  GS_DATA-WAERS = LV_WAERS.
  APPEND GS_DATA TO GT_DATA.

  DO 12 TIMES.

    CLEAR GS_DATA.
    GS_DATA-MON = SY-INDEX.
    GS_DATA-MON_TXT = SY-INDEX && '월'.
    GS_DATA-WAERS = 'KRW'.

    LV_MONTH = SY-INDEX.

    SELECT SINGLE *
      INTO CORRESPONDING FIELDS OF LS_T040
      FROM ZTFC_FIT040
      WHERE GJAHR = GV_YEAR
        AND MON = LV_MONTH
        AND SKANR = PV_NODE_KEY.

      GS_DATA-DEBIT = LS_T040-DEBIT.
      GS_DATA-CREDIT = LS_T040-CREDIT.
      GS_DATA-BALANCE = LS_T040-BALANCE.
      APPEND GS_DATA TO GT_DATA.

*   차트
      CATEGORY = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Category' PARENT = CATEGORIES ).
      CATEGORY->IF_IXML_NODE~SET_VALUE( GS_DATA-MON_TXT ).

*   차변
      DEBIT_STRING = GS_DATA-DEBIT * 100.
      POINT = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Point' PARENT = SERIES_DEBIT ).
      VALUE = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Value' PARENT = POINT ).
      VALUE->SET_ATTRIBUTE( NAME = 'type' VALUE = 'y' ).
      VALUE->IF_IXML_NODE~SET_VALUE( DEBIT_STRING ).

*   대변
      CREDIT_STRING = GS_DATA-CREDIT * 100.
      POINT = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Point' PARENT = SERIES_CREDIT ).
      VALUE = GO_IXML_DATA_DOC->CREATE_SIMPLE_ELEMENT( NAME = 'Value' PARENT = POINT ).
      VALUE->SET_ATTRIBUTE( NAME = 'type' VALUE = 'y' ).
      VALUE->IF_IXML_NODE~SET_VALUE( CREDIT_STRING ).

    ENDDO.

    CLEAR GS_DATA.
    GS_DATA-MON = 13.
    GS_DATA-MON_TXT = '차기이월'.
    GS_DATA-CARRYOVER = LS_T040-BALANCE.
    GS_DATA-BALANCE = LS_T040-BALANCE.
    GS_DATA-WAERS = 'KRW'.
    APPEND GS_DATA TO GT_DATA.

* 차트
    GO_OSTREAM = GO_IXML_SF->CREATE_OSTREAM_XSTRING( XDATA ).
    GO_IXML_DATA_DOC->RENDER( GO_OSTREAM ).
    GO_CHART->SET_DATA( XDATA = XDATA ).
    GO_CHART->RENDER( ).

ENDFORM.

여담

누적 막대 그래프를 고객이 요구한다고 회사에서 얼핏 들어서
혼자 누적 막대 그래프를 그려보려 했는데 결국 실패했다.

나중에 그 요구사항을 받으신 선임분께 어떻게 했는지 여쭤봐야겠다.

위의 방법으로는 꺾은선, 막대 그래프만 커스터마이징하여 잘 그릴 수 있다.

그 외 그래프는 Sap Chart Designer 라는 프로그램을 다운로드하여
XML을 뽑아내서 그려야 한다고 하는데
어찌저찌 Sap Note를 뒤져 프로그램을 찾아서 다운로드했지만 sapchartd.ocx 파일이 없다며 에러를 뱉어서 실패했다.

https://userapps.support.sap.com/sap/support/knowledge/en/3566703

3566703 - Chart Designer Execution Failure Post SAP GUI 800 (64bit) Installation | SAP Knowledge Base Article

3566703 - Chart Designer Execution Failure Post SAP GUI 800 (64bit) Installation Symptom After installing SAP GUI 800 (64bit), the execution of ChartDesigner700.exe is not possible.Initial error message: "Component "comdlg32.ocx" or one of its dependencies

userapps.support.sap.com